Ebene Kurven

Analysis I,  D-MATV/D-MATL
HS 2008
Giovanni Felder, ETH

Dieses Notebook berechnet die Krümmung in jedem Punkt einer in Parameterdarstellung gegebenen ebenen Kurve. Die Kurve und ihre Evolute werden graphisch dargestellt. Der Krümmungskreis wird durch eine Animation gezeigt.
[Shift-Enter in Inputzellen drücken]
Parameterdarstellung der Kurve. Der Parameter t läuft über das Intervall [a,b]:

Clear[x,y,X,Y,k]

x[t_]:=2Cos[t] 
y[t_]:= Sin[t]
a=0;b=2Pi;

ParametricPlot[{x[t],y[t]},{t,a,b}]  (* Plot curve t->(x(t),y(t)) for a<t<b *)

Die Krümmung k(t) im Punkt (x(t),y(t)) ist die Ableitung nach t des Steigungswinkel in (x(t),y(t))

k[t_]:=(x'[t]y''[t]-x''[t]y'[t])/(x'[t]^2+y'[t]^2)^(3/2)

Der Krümmungskreis im Punkt (x(t),y(t)) hat dieselbe Tangente und Krümmung als die gegebene Kurve K in (x(t),y(t)).  Sein Mittelpunkt (X(t),Y(t)) beschreibt die Evolute von K.

X[t_]:=x[t]-(1/k[t])y'[t]/Sqrt[x'[t]^2+y'[t]^2]
Y[t_]:=y[t]+(1/k[t])x'[t]/Sqrt[x'[t]^2+y'[t]^2]

Simplify[{X[t],Y[t]}]

Graphische Darstellung der Kurve und ihrer Evolute:

ParametricPlot[{{x[t],y[t]},{X[t],Y[t]}},{t,a,b},AspectRatio->Automatic]

Animation: Der Krümmungskreis wird für eine Folge von Parameterwerten gezeichnet.

Animate[ParametricPlot[
{{x[t],y[t]},{X[s]+Cos[t]/k[s],Y[s]+Sin[t]/k[s]}},{t,a,b},
AspectRatio-> Automatic,                (* same scale for x- and y-axis *)
PlotRange->{{-4,4},{-7,7}}], (* same range for all frames *)
 {s,a,b}]